Rood kruis door netwerkdrive

[Tino]

Hallo,
Ik heb al van alles afgezocht maar ik kom er niet uit.
Ook heb ik het in oud topic gepost maar geen reactie.

Dus vandaar dat ik het zo probeer

Ik heb windows Vista home premium , ik heb een vpn verbinding ingesteld maar er komt een rood kruis door de mappen dit probleem heb ik al meer gelezen, ik heb het script @echo van wizjos gebruikt.
De netwerk schijf van buiten af  verdwijnt als het script op start.
Maar de schijf komt niet terug

Waar doe ik wat fout ?

Alvast super bedankt voor de hulp

Code: [Selecteer]

@ECHO OFF
REM Edit by Wizjos 9/3/2013
REM !---- Command Script that waits until the network connection to a (local) network resource has been
REM !---- established, and only then mounts specified network locations as mapped drives.
REM !---- Useful in case setting up the network connection might take long following startup.
REM !---- This might e.g. apply to WiFi connections
REM !---- Script verified for WinXP (English version)

REM !---- Define the NAS IP-address or network name (e.g. "192.168.1.5" or "Diskstation"), but use -NO- quotes (")
REM !---- IP-address should always work; network name only when client and NAS are in the same Workgroup/Domain
SET nas_ip=10.9.0.6

REM !---- Use this section if NAS-username and/or -password differs from Windows-username and/or -password
REM !---- Omit this section ("REM" all lines) if Windows and NAS user-name and -password are identical
SET nas_usr=Heb ik in gevuld
REM !---- Use the next line to be prompted for the NAS-user password. Preferred solution, safe
REM SET /p nas_pwd=Please provide password for remote user %nas_usr% on \%nas_ip%: ?
REM !---- Use the next line to put the NAS-user password in this file. Non-preferred, unsafe
SET nas_pwd=heb ik ingevuld

REM !---- Modify the following variables according to need; value always between 1 and 254 (incl)
SET /a seconds_between_pings=3
SET /a max_attempts=90
SET /a seconds_of_end_message=10
SET /a min_good_pings=3

REM !---- Use the next line if you want to delete the links to ALL mapped network drives
NET USE * /DELETE
REM !---- Use the next line(s) (and modify drive-letters) if you want to delete specific mapped network drives
REM NET USE K: /DELETE
REM NET USE L: /DELETE

SET /a attempts=1
SET /a good_pings=0
SET display=Waiting for connection to %nas_ip% .
REM !--- Mind the white-space ( ) behind the last period (.) above !

:try_again
CLS
ECHO %display%
REM !--- The following line serves as a "wait" statement
PING -n %seconds_between_pings% -w 1 %nas_ip% >NUL
REM !--- You might (?) need to change "Reply from" below for non-English Windows versions
PING -n 1 -w 200 %nas_ip% | FIND "Antwoord van %nas_ip%" >NUL
IF %ERRORLEVEL% EQU 0 (SET /a good_pings+=1)
IF %good_pings% EQU %min_good_pings% GOTO :conn_established
SET display=%display:. =.. %
SET /a attempts+=1
IF %attempts% LEQ %max_attempts% GOTO :try_again

ECHO.
ECHO Connection to %nas_ip% failed to establish within reasonable time
ECHO.
ECHO Unable to map network drive(s) to %nas_ip%
ECHO.
GOTO :almost_oef

:conn_established
ECHO.
ECHO Connection to %nas_ip% established
ECHO.
ECHO Now mapping network drive(s)

IF N%nas_usr%==N (SET userdata="") ELSE (SET userdata="/USER:%nas_usr% %nas_pwd% ")
rem also OK for XP: IF defined nas_usr (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
rem not OK for XP: IF EXIST %%nas_usr%% (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
REM !---- add line(s), change drive-letter (e.g. K:) and NAS folder-name (e.g. nas_folder1) according to need
NET USE K: \%nas_ip%\homes %userdata:"=%/PERSISTENT:NO


:almost_oef
PING -n %seconds_of_end_message% -w 1 %nas_ip% >NUL

[Birdy]

Ook heb ik het in oud topic gepost maar geen reactie.

Gezien ja, maar als je daar (nog) geen reactie hebt gehad (sinds gisteren 18:00) dan wil dat toch niet zeggen dat je weer dezelfde vraag stelt maar dan in een nieuwe topic ? Dat is niet handig.
Die andere, in oude Topic, verwijder ik maar dan.

[Tino]

Mijn excuus,
ik was vandaag een dagje vrij en wilde graag aan werken

een beetje ongeduldig dus

excuus

ik wacht rustig af

[Erwin1]

Ik begrijp niet precies wat je gedaan hebt, maar werkt VPN verbinding zelf wel? En wat geeft de VPN log aan?

[Tino]

Hallo
Bedankt voor je reactie

De VPN werkt wel, sterker nog als ik op het rode kruis druk
kom ik gewoon in de map.

[Erwin1]

Kun je eens een printscreen maken van het rode kruis?

[Tino]

Hallo,
Hierbij een printscreen.

Ik heb ergens gelezen dat het komt door dat netwerkdrive eerst opstarten en dan pas de vpn verbinding.

groet

[Ben(V)]

Dat is helemaal correct.
Bij het opstarten van windows worden de persistant network drive gekoppeld en als die niet geconnect kunnen worden dan komt er een kruis door.
Als je dan later de vpn in de lucht brengt zal pas als windows weer probeert die netwerk drive te benaderen dat kruis verdwijnen.

Zie eigenlijk niet wat het probleem is, klik op een kruis en weg is ie.

[Tino]

Het is ook niet een groot probleem..
het is meer dat ik het bij mijn ouders ook heb aangelegd en dat alle programma's (word,itunes,Enz.) rechtstreeks op die map
heb aangesloten dat alles daar automatische opslaat. Maar als windows een rood kruis er door heen zet dan herkent word de schijf ook niet

en dat is vrij lastig

[Hutje]

Hoe maken je ouders nu contact dan?
Start de VPN verbinding automatisch of moeten ze daar een handeling voor verrichten ?


Sent from my iPad using Tapatalk

[Robbedoes]

Handiger is een bestandje (naam.cmd) aanroepen bij opstarten die de share maakt.
Eigenlijk ook de bestaande eerst opruimt waardoor je geen conflicten krijgt.
Inhoud (voorbeeld):

REM Zet netshare Iso van NAS op driveletter I
net use I: /delete /yes
net use I: "\\Synology\Iso" /persistent:no
exit

Op die CMD file maak je dan een snelkoppeling in Opstarten van die user of een taak ik Windows taakbeheer.
Bij die laatste kun je hem ook vertraagd opstarten 30 seconden na aanloggen user.
Gebruik ik ook zo omdat ik soms ook last had dat de PC bij opstarten bleef wachten totdat de NAS uit sleep gekomen was.
Geen moeilijke scripts nodig dus.

[Tino]

Bedankt voor alle reactie's

Mijn ouders maken er nu nog geen gebruik van, ik weet alleen dat wanneer ik het aan sluit
zo makkelijk mogelijk moet werken en dat hun zo min mogelijk handelingen moeten doen.


Ik ben een redelijke leek,
Zou je me in stappen kunnen  vertellen hoe ik het moet opzetten?

Bedankt allemaal

[Robbedoes]

Een CMD bestand is gewoon een TXT bestand waarvan je de extensie wijzigt.
Je kunt de naam elke naam geven die je wilt, als jij het maar herkent.
Je kan mijn voorbeeld overnemen, voor Synology neem je het IP adres van de NAS.
Simpel copy en past, kies een driveletter die nooit gebruikt wordt.

Je kunt het handmatig uitvoeren door te dubbelklikken, of een snelkoppeling op het bureaublad te zetten en die te starten.
Als het werkt kun je het verder automatiseren.

[Tino]

top dankjewel..

hij verwijderd de map wel, maar hij komt niet terug enig idee waar ik mis doe ?

groet

[Birdy]

Ik heb getest, maar moest wel voor de 1e keer even inloggen.
Draai het script eerst even in de CMD box om te zien of er iets mis gaat of dat je ook eerst moet inloggen op de NAS.