Wachten met netwerk-akties tot verbinding met NAS OK is

[Plerry]

Het blijkt een in verschillende vormen regelmatig terugkerend probleem dat het
(zeker via een WiFi verbinding) lang kan duren voordat de netwerkverbinding naar je NAS
(of een andere netwerkresource) tot stand komt, terwijl diverse programma's al proberen
van de NAS gebruik te maken.
Ik heb daarvoor enige tijd geleden een command-script geschreven voor het mappen van NAS netwerkdrives
waarin herhaaldelijk naar je NAS wordt gepingt, totdat dat een aantal malen succesvol is geweest,
en pas daarna d.m.v. van "net use" commando's de gewenste netwerkdrives mapt.
Tijd om dat eens te delen.

Sla onderstaande code op in een bestand met de extensie ".cmd", verander naar behoefte de drive-letters
en folder-namen en REM of un-REM naar behoefte en sla het op in de Windows startup-folder.
Edit: en wijzig (indien relevant) in de regel "SET nas_usr=NasUserName" de "NasUserName" in de gewenste user-name op de NAS.

Werkt bij mij probleemloos voor Engelstalige WinXP, maar zou (denk ik) ook moeten werken onder Vista en Win7.
Voor Nederlandstalige Windows moet mogelijk op de genoemde plaats iets worden aangepast, maar ik
kan dat niet controleren (uitsluitend Engelstalige Windows en SW).

Code: [Selecteer]

@ECHO OFF
REM !---- Command Script that waits until the network connection to a (local) network resource has been
REM !---- established, and only then mounts specified network locations as mapped drives.
REM !---- Useful in case setting up the network connection might take long following startup.
REM !---- This might e.g. apply to WiFi connections
REM !---- Script verified for WinXP (English version)


REM !---- Define the NAS IP-address or network name (e.g. "192.168.1.5" or "Diskstation"), but use -NO- quotes (")
REM !---- IP-address should always work; network name only when client and NAS are in the same Workgroup/Domain
SET nas_ip=192.168.1.6
rem SET nas_ip=Diskstation


REM !---- Use this section if NAS-username and/or -password differs from Windows-username and/or -password
REM !---- Omit this section ("REM" all lines) if Windows and NAS user-name and -password are identical
SET nas_usr=NasUserName
REM !---- Use the next line to be prompted for the NAS-user password. Preferred solution, safe
SET /p nas_pwd=Password for remote user %nas_usr% on \%nas_ip%: ?
REM !---- Use the next line to put the NAS-user password in this file. Non-preferred, unsafe
rem SET nas_pwd=NasPassword

REM !---- Modify the following variables according to need; value always between 1 and 254 (incl)
SET /a seconds_between_pings=3
SET /a max_attempts=90
SET /a seconds_of_end_message=10
SET /a min_good_pings=3


REM !---- Use the next line if you want to delete the links to ALL mapped network drives
rem NET USE * /DELETE
REM !---- Use the next line(s) (and modify drive-letters) if you want to delete specific mapped network drives
rem NET USE K: /DELETE
rem NET USE L: /DELETE

SET /a attempts=1
SET /a good_pings=0
SET display=Waiting for connection to %nas_ip% .
REM !--- Mind the white-space ( ) behind the last period (.) above !

:try_again
CLS
ECHO %display%
REM !--- The following line serves as a "wait" statement
PING -n %seconds_between_pings% -w 1 127.0.0.1 >NUL
REM !--- You might (?) need to change "Reply from" below for non-English Windows versions
PING -n 1 -w 200 %nas_ip% | FIND "Reply from %nas_ip%" >NUL
IF %ERRORLEVEL% EQU 0 (SET /a good_pings+=1)
IF %good_pings% EQU %min_good_pings% GOTO :conn_established
SET display=%display:. =.. %
SET /a attempts+=1
IF %attempts% LEQ %max_attempts% GOTO :try_again

ECHO.
ECHO Connection to %nas_ip% failed to establish within reasonable time
ECHO.
ECHO Unable to map network drive(s) to %nas_ip%
ECHO.
GOTO :almost_oef

:conn_established
ECHO.
ECHO Connection to %nas_ip% established
ECHO.
ECHO Now mapping network drive(s)

IF N%nas_usr%==N (SET userdata="") ELSE (SET userdata="/USER:%nas_usr% %nas_pwd% ")
rem also OK for XP: IF defined nas_usr (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
rem not OK for XP: IF EXIST %%nas_usr%% (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
REM !---- add line(s), change drive-letter (e.g. K:) and NAS folder-name (e.g. nas_folder1) according to need
NET USE K: \\%nas_ip%\nas_folder1 %userdata:"=%/PERSISTENT:NO
NET USE L: \\%nas_ip%\nas_folder2 %userdata:"=%/PERSISTENT:NO

:almost_oef
PING -n %seconds_of_end_message% -w 1 127.0.0.1 >NULEdit: code "hersteld" na het wegvallen van backslashes bij de vertaling naar het nieuwe forum-format.

Deze code wordt verstrekt "as is".
Uiteraard kan het gebruikte wacht-principe ook worden gebruikt om andere programma's dan netwerkmappings pas op
te starten als de netwerkverbinding tot stand is gekomen.
Vervang hiertoe de sectie waarin de netwerkdrives middels "net use" worden gemapt door het commando om
de gewenste applicatie op te starten.

Succes!

Plerry

[Holy]

Hallo Plerry,

Het script aangepast voor mijn situatie (Vista), echter het gedeelte "SET nas_usr=NasUserName" en "SET nas_pwd=NasPassword" wil maar niet werken.  Tijdens het opstarten blijft er gevraagd worden om de username en het wachtwoord.
Heb derhalve de betreffende regels uitgeschakeld middels REM, en verderop in het script bij netwerkmappings een kleine wijziging aangebracht volgens:
net use M: \DISKSTATIONhome wachtwoord /gebruiker:Holy
net use N: \DISKSTATIONmusic
enz.

Merk hierbij op dat alleen achter de eerst genoemde share de username en wachtwoord hoeven te worden opgegeven, de rest volgt dan netjes.  

Overigens zoals je al noemde, het "Reply from" vervangen door "Antwoord van" voor mijn Nederlandse Vista.

Het geheel werkt nu keurig, het wacht eerst netjes het pingen af om dan vervolgens de mapping van de share's te verzorgen.

greetz, Holy

[Plerry]

...Het script aangepast voor mijn situatie (Vista), echter het gedeelte "SET nas_usr=NasUserName" en "SET nas_pwd=NasPassword" wil maar niet werken.  Tijdens het opstarten blijft er gevraagd worden om de username en het wachtwoord. ...

Heel merkwaardig!
Uiteraard is de door jou gebruikte oplossing ook prima bruikbaar, maar ik snap graag waarom het niet werkt.
Ik heb het zojuist zelf ook eens onder Vista (Engels, 32-bit) geprobeerd, maar bij mij werkt het gewoon:
NAS_User gespecificeerd met "SET nas_usr=[JouwNasUserName]" en dan geprompt worden voor het password.
Pas daarna start het pingen en daarna het mounten.
Wanneer werd er bij jou gevraagd om user/password, voor of na het pingen?
Je gebruikt toch geen aanhalingstekens/quotes rond je user-naam en password?
Gaat de specificatie van je NAS-IP of naam via "SET nas_ip=[Jouw_NAS_IP]" wel goed?

Merk hierbij op dat alleen achter de eerst genoemde share de username en wachtwoord hoeven te worden opgegeven, de rest volgt dan netjes.  

Ik wist niet dat die user credentials kennelijk worden onthouden voor de volgende
"net use ..." (binnen dezelfde command-shell?). Ook weer wat geleerd ...

Overigens zoals je al noemde, het "Reply from" vervangen door "Antwoord van" voor mijn Nederlandse Vista.

Als iemand hiervoor een meer algemene (taal onafhankelijke) oplossing heeft houd ik me aanbevolen.
Bij het evalueren van het script bleek echter dat ik (afhankelijk van de omstandigheden),
indien het gevraagde IP of de gevraagde naam niet bekend of niet bereikbaar waren,
soms antwoord kreeg van een gateway of DNS server en niet van mijn NAS.
Vandaar de keuze voor "reply from %nas_ip".
Je moet zeker weten dat het antwoord van je NAS komt en niet van een andere schakel in de keten.

In ieder geval fijn te horen dat anderen het onderliggend principe ook met vrucht gebruiken.

Plerry

[Holy]

Hallo Plerry,

Zoals beloofd even een terugkoppeling:  heb het originele bestand van jou genomen en ben met een schone lei begonnen. Inmiddels was de laptop ook weer voorzien van een verse "Vista Home Premium Nederlands" installatie, dus maar eens gekeken wat het werd.
Heb mijn NAS_IP opgegeven, mijn NAS_gebruikersnaam, "Reply from  vervangen door Antwoord van", en de NAS map "home" gespecificeerd om een mapping naar te maken.
Bestand opgeslagen en uitgevoerd:  er werd keurig om het wachtwoord gevraagd en na ingeven daarvan, werd de connectie gemaakt en de share gemapt  
Vervolgens met de hand de share verwijderd en het bestand aangepast zodat er niet meer naar het wachtwoord werd gevraagd, maar automatisch wordt ingevuld > oké, werkt als een zonnetje.
Hierna nogmaals de share verwijderd en inplaats van NAS_IP de NAS_Naam ingegeven.  Hiermee wil het echt niet lukken, wat ik ook als naam ingeef (kleine letters, hoofdletters en alle combinaties daarmee) ondanks dat laptop en NAS in dezelfde werkgroep zitten.

Conclusie:  Waarschijnlijk heeft in een eerdere poging mijn Vista roet in het eten gegooid, immers er werkten op zeker moment wel meer dingen niet, dus dat lijkt aannemelijk. Met uitzondering van de NAS_naam werkt alles dus naar behoren en heb je een mooi bestand afgegeven, waarvoor mijn dank!

greetz, Holy

[Goofy62]

Werkt dit script ook op een computer met meerdere accounts?

Ik heb voor mijn kinderen accounts aangemaakt met minder rechten op de DiskStation en wil derhalve niet dat ze aangemeld worden als admin  ;-)

Reden waarom ik het vraag: ik heb het programma ChildControl op alle PC's hier in huis staan. Dat programma KAN gebruik maken van een settings-bestand dat op een NAS staat, zodat centraal wordt bijgehouden hoeveel tijd de kinderen op de verschillende computers achter internet zitten. Ik merk echter dat het programma ChildControl al op zoek gaat naar die settings-file VOORDAT er een verbinding met de NAS is; als dat gebeurt schakelt het programma ChildControl over naar een lokale settings-file en dat mag dus niet.

[Plerry]

Toch nog even wat verder in gedoken ...
Het "net use ..." commando kan uitstekend uit de voeten met een netwerknaam in plaats van een IP-adres.
Daar zat het probleem dan ook niet.

Het probleem blijkt te zitten in het antwoord op een "ping" commando bij het gebruik van een netwerknaam:

Code: [Selecteer]

C:>ping -n 1 -w 200 diskstation
Pinging diskstation [192.168.1.5] with 32 bytes of data:
Reply from 192.168.1.5: bytes=32 time<1ms TTL=64
...Het ligt dus aan het feit dat in "Reply from ..." de netwerknaam uiteraard is vervangen door het IP-adres,
terwijl het script bij gebruik van een netwerknaam wel op "Reply from [netwerknaam]" controleert.

In de huidige vorm werkt het script dus alleen met IP-adres, en niet met netwerknaam van de NAS.

Het blijkt dus gekoppeld aan de eerder genoemde mogelijk betere oplossing dan het gebruik van
het Windows-taal afhankelijke "Reply from ...".
Ik was daarvoor als suggestie tegengekomen om te controleren op "TTL=" in plaats van "Reply from ...",
maar dat blijkt niet robuust, omdat je soms antwoord kan krijgen van een andere schakel in de keten,
die wel ook "TTL=" gebruikt in het antwoord.

Plerry

[Holy]

Hallo Plerry,

Helder verhaal. Heb voor de gein ook maar eens een ping vanaf de cmd naar diskstation gedaan en krijg keurig antwoord....alleen iets anders dan ik zou verwachten.  Als modem/router maak ik gebruik van een FritzBox 7170 van XS4ALL, Als ik nu een ping doe naar de diskstation, krijg ik antwoord van diskstation.fritz.box [192.168.0.23]...

C:>ping diskstation

Pingen naar diskstation.fritz.box [192.168.0.23] met 32 bytes aan gegevens:
Antwoord van 192.168.0.23: bytes=32 tijd=3 ms TTL=64
Antwoord van 192.168.0.23: bytes=32 tijd=4 ms TTL=64
Antwoord van 192.168.0.23: bytes=32 tijd=3 ms TTL=64
Antwoord van 192.168.0.23: bytes=32 tijd=2 ms TTL=64

Ping-statistieken voor 192.168.0.23:
    Pakketten: verzonden = 4, ontvangen = 4, verloren = 0
    (0% verlies).

De gemiddelde tijd voor het uitvoeren van één bewerking in milliseconden:
    Minimum = 2ms, Maximum = 4ms, Gemiddelde = 3ms

Ik heb zoiets nog niet eerder gezien, wellicht dat jij er iets mee kan.

Greetz, Holy

[Holy]

Hallo Goofy62,

Lijkt mij dat dit ook op meerdere accounts moet werken, al zul je dan per account een eigen bestand met code moeten maken; immers elke ingelogde gebruiker dient op een andere map op de NAS terecht te komen.
Indien je de bestanden gereed hebt , deze per gebruiker laten uitvoeren vanuit de ingelogde gebruiker uit de map  opstarten.
Gewoon proberen lijkt mij, het lukt of het lukt niet    Kan verder denk ik géén ellende veroorzaken.

Greetz, Holy

[Plerry]

Werkt dit script ook op een computer met meerdere accounts? ...

Het lijkt me wel.
ChildControl zal (naar ik vermoed) in het bestand op je NAS op zoek gaan naar de Windows-user naam
waaronder op de PC is ingelogd en de daarbij horende instellingen toepassen.
Het lijkt dus niet nodig op je NAS per Windows-user verschillend in te loggen.
Je kan het *.cmd wacht-script bestand dus gewoon opslaan in
C:Documents and SettingsAll UsersStart Menu

Indien ChildControl (behalve voor beheer) nu slechts hoeft te kunnen lezen in de NAS folder,
kan je een NAS-user aanmaken die in de bewuste NAS-folder slechts leesbevoegdheid heeft.
In het *.cmd script gebruik je dan die NAS-user en het bijbehorend password, dat nu wel in
de *.cmd-file moet staan, omdat je kinderen die niet (hoeven te) weten.
Na het mounten van de bewuste NAS-folder middels het "net use ..." commando zou je dan
in het script ook ChildControl moeten opstarten met de passende opdracht.

Voor het beheer moet je echter wel schrijftoegang hebben tot de bewuste folder op je NAS-drive.
Dat zou je kunnen afvangen door in het script, op basis van de Windows-user die heeft ingelogd
te differentieren naar de NAS-user/password combinatie waarmee wordt ingelogd.
Dat zou bijvoorbeeld kunnen door in het script de regels die nas_usr en nas_pwd bepalen te vervangen door

Code: [Selecteer]

set nas_usr=read_only_nas_usr
set nas_pwd=read_only_nas_pwd
if NOT %username%==AdminUser GOTO :standard_user
set nas_usr=read_write_nas_usr
set /p nas_pwd=Password for remote user %nas_usr% on \%nas_ip%: ?
:standard_userOF

Code: [Selecteer]

wijzig
IF N%nas_usr%==N (SET userdata="") ELSE (SET userdata="/USER:%nas_usr% %nas_pwd% ")
in
IF %username%==AdminUser (SET userdata="* /USER:read_write_nas_usr ") ELSE (SET userdata="read_only_nas_pwd /USER:read_only_nas_usr ")De "AdminUser" is dan de usernaam waarmee jij zelf op je Windows machines inlogt.
Uiteraard dien je ook "read_only_nas_usr", "read_only_nas_pwd" en "read_write_nas_usr" door de juiste
waarden te vervanegn. Gebruik daarbij geen quotes (").

Ongeacht de Windows-user heb je dan altijd dezelfde drive-letter waarop ChildControl zijn "ding" kan doen.
Echter, alleen wanneer jij zelf bent ingelogd heb je daar ook schrijfbevoegdheid.
Dat het read-only password in het script staat is niet zo erg, maar voor het read-write wachtwoord wordt je
netjes geprompt. De tweede oplossing is iets netter, omdat je dan (wanneer aan de orde) door "net use ..."
wordt geprompt om je password. Dat is inzichtbaar bij het intikken. De eerste oplossing niet.

Plerry

[pauluz_first]

Zou het kunnen zijn dat met dit wachtscript onder Windows 7 64bits. Dat als je bijvoorbeeld Word bestanden netjes afgesloten hebt, je pc afsluit, op een of andere manier de 'cache' niet goed geleegd wordt en hierdoor bestanden corrupt raken.
En de bestanden daarna dus niet opnieuw op te roepen zijn?

En dat het beter mogelijk beter werkt onder het visual basic script van Gido  http://www.synology-forum.nl/viewtopic.php?f=70&t=4839 omdat dit nieuwe technologie /beter aansluit met Windows 7.

Of is er ook een afsluit commando, wat voor het afsluiten van je pc ervoor zorgt dat de cache weggeschreven wordt naar je nas?

[discorobinson]

ik snap het eigelijk niet goed hier maar ik maak nooit netwerkverbindingen maar altijd koppelingen naar een map en dat werkt altijd en overal op mijn laptop?? en draadloos

[Plerry]

Zou het kunnen zijn dat met dit wachtscript onder Windows 7 64bits. Dat als je bijvoorbeeld Word bestanden netjes afgesloten hebt, je pc afsluit, op een of andere manier de 'cache' niet goed geleegd wordt en hierdoor bestanden corrupt raken.
En de bestanden daarna dus niet opnieuw op te roepen zijn?

En dat het beter mogelijk beter werkt onder het visual basic script van Gido  http://www.synology-forum.nl/viewtopic.php?f=70&t=4839 omdat dit nieuwe technologie /beter aansluit met Windows 7.

Of is er ook een afsluit commando, wat voor het afsluiten van je pc ervoor zorgt dat de cache weggeschreven wordt naar je nas?

Jammer dat je eerste vraag niet uit de verf komt. Je vraag is daarom moeilijk te beantwoorden.
Omdat het script slechts het initiële mounten van netwerkdrives uitstelt tot die netwerkdrives daadwerkelijk beschikbaar zijn (en verder niets), zou het script niet verantwoordenlijk moeten kunnen zijn voor het niet correct afsluiten van bestanden.
Los van het feit dat het script van Gido functioneel niet precies doet wat de bedoeling is
(zie http://www.synology-forum.nl/viewtopic.php?f=115&t=5137#msg29887 en de daarop volgende discussie)
is er geen principieel verschil tussen het gebruik van een command-shell script of een VB-script.

ik snap het eigelijk niet goed hier maar ik maak nooit netwerkverbindingen maar altijd koppelingen naar een map en dat werkt altijd en overal op mijn laptop?? en draadloos

Dat is precies wat het "net use ..." commando doet: een koppeling maken naar een netwerkmap.

@pauluz_first en @discorobinson
Zoals diverse malen aangegeven in de discussie rond dit onderwerp manifesteert het op te lossen probleem zich vooral in een Windows XP omgeving in combinatie met het gebruik van een WiFi verbinding.
In de tijd van conceptie van XP stond WiFi nog in de kinderschoenen. WiFi is daardoor niet in XP geintegreerd, maar is achteraf toegevoegd. Het activeren van WiFi en de bijbehorende drivers hangt daardoor binnen XP aan de achterste mem. Zeker op een bedrijfs-laptop, waarop de IT afdeling alle mogelijke "overhead" heeft geinstalleerd kan het daarom tot meerdere minuten duren voordat WiFi up-and-running is.
In Windows 7 is dat geheel anders. Daarin is WiFi volledig geintegreerd en is al zeer snel na het opstarten beschikbaar. Daardoor zal het wachtscript daar zelden nodig/nuttig zijn.

Plerry