Het blijkt een in verschillende vormen regelmatig terugkerend probleem dat het
(zeker via een WiFi verbinding) lang kan duren voordat de netwerkverbinding naar je NAS
(of een andere netwerkresource) tot stand komt, terwijl diverse programma's al proberen
van de NAS gebruik te maken.

Plerry heeft daarvoor enige tijd geleden een command-script geschreven voor het mappen van NAS netwerkdrives
waarin herhaaldelijk naar je NAS wordt gepingt, totdat dat een aantal malen succesvol is geweest,
en pas daarna d.m.v. van "net use" commando's de gewenste netwerkdrives mapt. (origineel bericht: viewtopic.php?f=70&t=4839)
Tijd om dat eens een ereplaatsje te geven.

Sla onderstaande code op in een bestand met de extensie ".cmd", verander naar behoefte de drive-letters
en folder-namen en REM of un-REM naar behoefte en sla het op in de Windows startup-folder.
Wijzig (indien relevant) in de regel "SET nas_usr=NasUserName" de "NasUserName" in de gewenste user-name op de NAS.
Denk uiteraard ook om het IP-adres (SET nas_ip=) en het eventuele password (SET nas_pwd=).

@ECHO OFF
REM !---- Command Script that waits until the network connection to a (local) network resource has been
REM !---- established, and only then mounts specified network locations as mapped drives.
REM !---- Useful in case setting up the network connection might take long following startup.
REM !---- This might e.g. apply to WiFi connections
REM !---- Script verified for WinXP (English version)


REM !---- Define the NAS IP-address or network name (e.g. "192.168.1.5" or "Diskstation"), but use -NO- quotes (")
REM !---- IP-address should always work; network name only when client and NAS are in the same Workgroup/Domain
SET nas_ip=192.168.1.6
rem SET nas_ip=Diskstation


REM !---- Use this section if NAS-username and/or -password differs from Windows-username and/or -password
REM !---- Omit this section ("REM" all lines) if Windows and NAS user-name and -password are identical
SET nas_usr=NasUserName
REM !---- Use the next line to be prompted for the NAS-user password. Preferred solution, safe
SET /p nas_pwd=Password for remote user %nas_usr% on \%nas_ip%: ?
REM !---- Use the next line to put the NAS-user password in this file. Non-preferred, unsafe
rem SET nas_pwd=NasPassword

REM !---- Modify the following variables according to need; value always between 1 and 254 (incl)
SET /a seconds_between_pings=3
SET /a max_attempts=90
SET /a seconds_of_end_message=10
SET /a min_good_pings=3


REM !---- Use the next line if you want to delete the links to ALL mapped network drives
rem NET USE * /DELETE
REM !---- Use the next line(s) (and modify drive-letters) if you want to delete specific mapped network drives
rem NET USE K: /DELETE
rem NET USE L: /DELETE

SET /a attempts=1
SET /a good_pings=0
SET display=Waiting for connection to %nas_ip% .
REM !--- Mind the white-space ( ) behind the last period (.) above !

:try_again
CLS
ECHO %display%
REM !--- The following line serves as a "wait" statement
PING -n %seconds_between_pings% -w 1 127.0.0.1 >NUL
REM !--- You might (?) need to change "Reply from" below for non-English Windows versions
PING -n 1 -w 200 %nas_ip% | FIND "Reply from %nas_ip%" >NUL
IF %ERRORLEVEL% EQU 0 (SET /a good_pings+=1)
IF %good_pings% EQU %min_good_pings% GOTO :conn_established
SET display=%display:. =.. %
SET /a attempts+=1
IF %attempts% LEQ %max_attempts% GOTO :try_again

ECHO.
ECHO Connection to %nas_ip% failed to establish within reasonable time
ECHO.
ECHO Unable to map network drive(s) to %nas_ip%
ECHO.
GOTO :almost_oef

:conn_established
ECHO.
ECHO Connection to %nas_ip% established
ECHO.
ECHO Now mapping network drive(s)

IF N%nas_usr%==N (SET userdata="") ELSE (SET userdata="/USER:%nas_usr% %nas_pwd% ")
rem also OK for XP: IF defined nas_usr (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
rem not OK for XP: IF EXIST %%nas_usr%% (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
REM !---- add line(s), change drive-letter (e.g. K:) and NAS folder-name (e.g. nas_folder1) according to need
NET USE K: \%nas_ip%nas_folder1 %userdata:"=%/PERSISTENT:NO
NET USE L: \%nas_ip%nas_folder2 %userdata:"=%/PERSISTENT:NO

:almost_oef
PING -n %seconds_of_end_message% -w 1 127.0.0.1 >NULDeze code wordt verstrekt "as is".
Uiteraard kan het gebruikte wacht-principe ook worden gebruikt om andere programma's dan netwerkmappings pas op
te starten als de netwerkverbinding tot stand is gekomen.
Vervang hiertoe de sectie waarin de netwerkdrives middels "net use" worden gemapt door het commando om
de gewenste applicatie op te starten.

@Gido:
Tenzij ik iets mis, lijkt het erop dat jouw vb script slechts kijkt of de bewuste
netwerkresource beschikbaar is.
* Zo ja, dan wordt de netwerkdrive gemount
* Zo niet, dan worden alle netwerkdrives verwijderd
Er wordt, naar het zich laat aanzien, dus niet gewacht tot de netwerkresource (eindelijk ...) beschikbaar is.

...Je netwerk (draad of draadloos) is dan al lang geïnitialiseerd.

Met Windows 7 is dat mogelijk het geval, maar met XP of Vista voor WiFi bijna zeker niet.
Daar kan het tot enkele minuten duren voor eindelijk WiFi (incl bijbehorende driver) aktief is.
En daar zat nu net het probleem.
Zeker met een laptop van het werk, waarop de IT afdeling eerst een schier eindeloze reeks aan services laat opstarten kan het beschikbaar zijn van WiFi vaak excessief lang duren ... .
Maar, uiteraard zou je met een aanpassing in je vb-script ook daar die wachtfunctie kunnen toevoegen.
 

Je kan dat ook met een policy beleid doen en een vb scriptje.
...Ga naar start/uitvoeren en typ in gpedit.msc en druk op enter. ...

Of je dit middels policy kan doen hangt af van de Windows versie die je hebt (bij bijv. een "Home" versie niet) en,
bij bijv. een laptop van het werk, van de bevoegdheden die de systeembeheerder je heeft toegekend.
Als alternatief voor het gebruik van de policy kan je het script bestand ook in de Startup folder zetten.

Plerry

Met Windows 7 is dat mogelijk het geval, maar met XP of Vista voor WiFi bijna zeker niet.
Daar kan het tot enkele minuten duren voor eindelijk WiFi (incl bijbehorende driver) aktief is.
En daar zat nu net het probleem.

Dit kun je oplossen door het script nog niet gelijk uit te laten voeren bij het opstarten.

Voeg dit toe in je VBScript (bovenaan), de tijd is in milliseconden:

WScript.Sleep 15000

Citaat

Ik gebruik altijd Windows 7 Pro of Ultimate dus inderdaad de policy editor is niet aanwezig in de home versies, daar sta ik helaas niet altijd bij stil.

Voor de de mensen die een Home editie hebben van Windows kunnen het heel makkelijk laten opstarten door het script te kopiëren naar:

Windows XP: C:Documents and Settings<username>Menu StartProgramma'sOpstarten
Windows Vista & 7: C:Users<username>AppDataRoamingMicrosoftWindowsStart MenuProgramsStartup

Dit kun je doen bij elke versie van Windows, hierdoor heb je de gpedit.msc niet nodig. Ook een beetje overbodig voor de thuis gebruikers

@ Plerry,

Zou het programmaatje ook aanpasbaar zijn voor het probleem waar ik nu al maanden mee sukkel met mijn DS411+

" error 64 Specified Network Name is no longer available "

Ik gebruik SpeedCommander (maar met WindowsExplorer is het eender) en bij het kopiëren of verplaatsen
van bestanden van mijn PC (W7-ultimate ENG) naar mijn NAS loop ik regelmatig tegen deze fout aan.

De opdracht begint vlot maar stopt dan (en SpeedCommander "hangt") en dan moet ik een hele tijd
wachten tot de foutmelding verschijnt.

Zelf heb ik altijd gedacht dat de fout met mijn WD-EARS schijven te maken had met RAID5,
omdat de fout bijna altijd optreedt nadat er lange tijd niet meer naar de NAS geschreven is.
Ik heb tevergeefs geprobeerd om mijn hibernate-tijd te verhogen.
Ik had met dezelfde netwerkapparaten de fout niet met mijn 207+

Ik heb tevergeefs hulp gevraagd aan Synology-support, ondanks dat ze beslist hun best deden.

Zelf had ik gedacht dat bij de copy  opdracht de parameter
/z  (copies network files in restartable mode) soelaas zou kunnen brengen.

Zowel voor die aanpassing als voor een aanpassing aan uw opdracht weet ik niet
hoe ik dit specifiek moet uitvoeren voor het kopiëren/verplaatsen binnen SpeedCommander.
(Ik ben nog iemand uit het DOS-tijdperk)

Weet iemand dit? Ik sukkel nu al maanden met die fout.

Overweging: misschien zou het programma makkelijker aanpasbaar zijn op het niveau van het starten
van de globale toepassing (SpeedCommander), maar dan denk ik dat mijn NAS altijd zou moeten
actief zijn als ik mijn PC gebruik, wat nu lang niet altijd het geval is.

Dank voor dit vlugge antwoord.
Ik werk met een bedraad netwerk en ik heb tevergeefs geëxperimenteerd met hibernate instellingen.
Ik zie maar één oplossing meer (vooraleer ik nieuwe hardware koop): RAID5 opgeven en met 4 losse schijven werken.

Ook dit heb ik geprobeerd, nl. laptop van mijn vrouw, zelfde probleem.
Ik heb eigenlijk alles tevergeefs geprobeerd.
Ik had het probleem niet met mijn ds207+ met dezelfde netwerkuitrusting;
enkel gebruikte ik toen geen jumbo frames (9K).
Overigens zonder die jumbo frames brengt mijn 411+ er niets van terecht
wat transfersnelheid betreft.
Ik ben intussen bezig met 4 basic volumes te maken...

Mijn hoop was ijdel: nog altijd error 64.
Misschien een nieuwe router (E4200 Linksys?) kopen om de D-Link switch te vervangen?

Ik denk nog altijd dat de syno niet vlug genoeg uit slaaptoestand komt.
Kent iemand soms een opdracht (eventueel met Putty) om dit (uit slaaptoestand halen) te realiseren?
Een andere vraag is in welke mate het schadelijk is om hibernate uit te zetten?